一.概述
GNS3用CRT打开思科路由器的时候，会自动进行一些配置，比如主机名，登录超时等等。经过测试，EVE让CRT执行脚本，也可以实现上述功能。
二.前期准备
1.安装CRT，可以是绿色面安装的版本，测试用的是6.5的绿色版
2.准备脚本文件DyRouter.VBS，比如放在D盘根目录，脚本内容见最后附录
3.安装EVE-ng客户端
4.修改EVE-ng客户端里面的win10_64bit_sCRT.reg文件，修改完成后双击该文件导入注册表
[HKEY_CURRENT_USER\SOFTWARE\Classes\SecureCRT.telnet\shell\open\command]
@="\"C:\\Program Files\\VanDyke Software\\SecureCRT\\SecureCRT.exe\" /T %1"
键值修改为：
@="\"C:\\Program Files\\VanDyke Software\\SecureCRT\\SecureCRT.exe\" /script D:\\DyRouter.vbs /T %1"
[HKEY_CURRENT_USER\SOFTWARE\Classes\telnet\shell\open\command]
@="\"C:\\Program Files\\VanDyke Software\\SecureCRT\\SecureCRT.exe\" /T %1"
键值修改为：
@="\"C:\\Program Files\\VanDyke Software\\SecureCRT\\SecureCRT.exe\" /script D:\\DyRouter.vbs /T %1"
备注：CRT的具体路径根据实际情况进行修改。
三.配置浏览器
1.如果是chrome浏览器访问eve，点击已经运行的路由器，出现如下提示，勾上前面的方框，然后点击，打开SecureCRT Application即可：
.png)
3.如果是Firefox浏览器访问eve，点击已经运行的路由器，出现如下提示，勾上前面的方框，然后点击，打开链接即可：
.png)
三.附录
DyRouter.VBS脚本文件内容如下：
#$language = "VBScript"
#$interface = "1.0"
Option Explicit
Function mysubstring(srcString,bChar,eChar)
Dim fIndex,sIndex
fIndex=InStr(srcString,bChar)
sIndex=InStrRev(srcString,eChar)
mysubstring=Mid(srcString,fIndex+1,sIndex-fIndex-1)
End Function
Function ciscoDate()
dim em, y,m,d,h
Dim nowDate
nowDate=Now()
em=Array("January","February","March","April","May","June","July","August","September","October","November","December")
y=Year(nowDate)
m=em(Month(nowDate)-1)
d=Day(nowDate)
h=Time()
ciscoDate=h & " " & m & " " & d & " " & y
End Function
Sub main
On Error Resume Next
crt.Screen.Synchronous = True
crt.Screen.WaitForString "Console port"
crt.Screen.Send VbCr
Dim firstLine
Dim tabTitle
firstLine=crt.Screen.Get2(1,1,1,100)
tabTitle=mysubstring(firstLine,"""","""")
crt.Window.Caption= tabTitle
If crt.Screen.WaitForString("[yes/no]",5) Then
crt.Screen.Send "no" & VbCr
End If
crt.Screen.Send VbCr &VbCr
crt.Screen.WaitForString "Router>"
crt.Screen.Send "enable" & VbCr
crt.Screen.Send "conf terminal" & VbCr
crt.Screen.Send "no ip domain-lookup " & VbCr
crt.Screen.Send "hostname " & tabTitle & VbCr
crt.Screen.Send "line con 0" & VbCr
crt.Screen.Send "exec-timeout 0 0" & VbCr
crt.Screen.Send "logging synchronous" & VbCr
crt.Screen.Send "end" & VbCr
crt.Screen.Send "clock set " & ciscoDate() & VbCr
crt.Screen.Synchronous = False
End Sub
